Sheep Crossing — 12 of 18

Chapter - Actions

Section - Movement

Unsupervising is an activity.

Persevering something is an activity on directions.

Instead of going somewhere when the player is not in the boat:

let the present motion be the current action;

say "(first getting into the boat)[command clarification break]";

silently try entering the boat;

if the player is not in the boat, stop the action;

try the present motion.

Before going somewhere when the player is in the boat:

if the player is nauseated and the bear is in the boat:

now the player is not nauseated;

say "Acutely aware of your nausea, you attempt to keep the boat level, but it isn't enough; and soon [if the player is postbarf]you are dry-heaving over the side[otherwise if the player is guilty]the remains of your last victim make a daring escape into the river[otherwise]your breakfast becomes the river's newest tributary[end if]. You've barely gotten your stomach under control when the boat rocks suddenly.[paragraph break](press any key) > ";

wait for any key;

say "[paragraph break]Fighting back more nausea, you turn and feel the bear pushing at you with its head. You struggle to stay in the boat, but you're no match for the bear's strength. Already weakened by the departure of your breakfast, you are unable to fight the current as it carries you away.";

end the story saying "You have drowned.";

otherwise if the player is nauseated:

now the player is not nauseated;

say "Acutely aware of your nausea, you attempt to keep the boat level, but it isn't enough; and soon [if the player is postbarf]you are dry-heaving over the side[otherwise if the player is guilty]the remains of your last victim make a daring escape into the river[otherwise]your breakfast becomes the river's newest tributary[end if]. After taking a moment to recover, you make the rest of the journey feeling a bit lighter.";

now the player is postbarf;

otherwise:

say "You begin rowing."

Instead of going somewhere when the player is in the boat:

if the bear is in the boat and the bear is full:

say "The boat sits uncomfortably low in the water as you row out into the river. You try to avoid thinking about why the bear's breath smells so bad now...[paragraph break](press any key) > ";

wait for any key;

say "[paragraph break]The boat wobbles. You have a moment to turn around and see the bear--what is it trying to do, avoid the frigid water that seems to be pouring into the boat?--before it rocks the boat again, dumping you overboard. As the current carries you away, you curse your lack of swimming lessons.";

end the story saying "You have drowned.";

otherwise:

continue the action.

The persistent direction is a direction that varies. The persistent direction is initially down.

The player persistence is a number that varies. The player persistence is initially 0.

After doing anything except going nowhere:

now the player persistence is 0;

now the persistent direction is down;

continue the action.

Rule for persevering a direction (called erewhon):

if the persistent direction is not erewhon:

now the player persistence is 0;

now the persistent direction is erewhon;

increment the player persistence.

Instead of going nowhere:

if the noun is a direction:

carry out the persevering activity with the noun;

if the player persistence is at least 3:

say "Ignoring [if the sheep is carrying the fluff and the player is not carrying the sheep]the slowly receding calls of your sheep[otherwise]the stares the bear must surely be giving you[end if], you trudge off towards the woods to leave it all behind. Grandmother can pay someone to deliver her groceries instead of making you do it for free![paragraph break]You have a childhood friend in the next town who can forge identification papers for you; all you have to do is get through the woods without being eaten by wolves...";

end the story saying "Nobody who claims to be you is ever heard from again.";

otherwise if the sheep is carrying the fluff and the player is not carrying the sheep:

say "[if the player persistence is less than 2]Before you can get very far,[otherwise]You get a little farther before[end if] you are called back by the anxious bleating of your sheep.";

otherwise:

say "The path to Grandmother's house doesn't look [if the player persistence is less than 2]terribly easy[otherwise]any easier[end if] in that direction."

The Dilapidated shack is a room.

Instead of going east in the East bank:

carry out the persevering activity with east;

if the player persistence is at least 3:

if the player is in the boat:

repeat with the passenger running through animals in the boat:

silently try dropping the passenger;

repeat with the passenger running through animals carried by the player:

silently try dropping the passenger;

say "Overwhelmed by [if the player is in the East bank for the first time]an inexplicable drowsiness[otherwise]frustration[end if], you leave your goods on the riverbank and head home to steal a nap.";

move the player to the Dilapidated shack, without printing a room description;

carry out the unsupervising activity;

say "(press any key) > ";

wait for any key;

say "[paragraph break]You return better rested but not really sure of the time anymore.";

move the player to the East bank;

otherwise if the player persistence is less than 2:

say "It's a long way back home; why don't you go west to Grandmother's house first?";

otherwise:

say "You can go home for a nap after you give Grandmother her groceries."

Instead of going west in the West bank:

if there are no portable animals in the East bank and there are no corpses in the East bank and there are no corpses in the West bank:

if the player is in the boat:

say "(first getting out of the boat)[command clarification break]";

silently try exiting;

repeat with item running through things carried by the player:

silently try dropping item;

if the number of animals in the West bank is the gift count:

end the story finally saying "You proceed happily toward Grandmother's house, with your gifts for her in tow. The day is going well.";

otherwise:

carry out the persevering activity with west;

if the player persistence is at least 3:

let L be the list of portable things in the East bank;

add the list of corpses in the West bank to L;

say "You forge ahead toward Grandmother's house, abandoning [L with definite articles].[paragraph break](press any key) > ";

wait for any key;

say "[paragraph break]Not having wasted any more time trying to herd your annoyingly high-maintenance cargo, you manage to reach the house well before dusk. 'Perfect! You're just in time for dinner!', you hear as you knock.[paragraph break](press any key) > ";

wait for any key;

say "[paragraph break]But Grandmother's face falls when she sees that you haven't brought everything she asked for. So like any experienced cook, she improvises...";

end the story saying "You have been eaten by Grandmother.";

otherwise if the player is carrying the sheep or the sheep is not carrying the fluff:

say "[if the player persistence is less than 2]You[otherwise]No, really, you[end if] seem to be missing something...";

otherwise:

decrement the player persistence;

continue the action.

Instead of going outside, say "You are already outside."

Instead of going inside, say "You see no buildings to enter."

Instead of going down, say "Down to the river is about as far down as you're really willing to go."

Understand "home" as east.

Understand "to Grandmother's house" as west.

Understand "to Grandma's house" as west.